C# & JavaScript

今回は「ECMAScript2016 (ES7)」についてまとめます。

ECMAScript 2016 (ES7) ではあまり機能追加されず、以下の2点だけ追加されたようです。 といっても、どちらも利用シーンは多そうな機能なのでぜひ覚えておきたいものです。

Array.prototype.includes()

今まで配列要素に指定した要素が含まれているかどうかを調べようとすると .indexOf() の戻り値が 0以上 であることを確認していました。 これだとコードで意味が分かりづらいので .includes() で読みやすくしようといった流れです。

構文

arr.includes(search [, fromIndex])

配列arr 中に 指定された要素 search が含まれている場合、 true を返します。 それ以外の場合、 false を返します。 fromIndex を指定した場合、そのインデックス以降の要素に対してマッチする要素があるかどうかを返します。

サンプルコード

var arr = ["a", "b", "c"];
console.log(arr.includes("b"));  // -> true
console.log(arr.includes("d"));  // -> false

arr[arr.length] = NaN
console.log(arr.includes(NaN));  // -> true

指数演算子

一般的な言語には「指数演算」の演算子が定義されていますが、なぜいか JavaScript には存在しませんでした。 （一応、 Math.pow() はありましたが、演算子（オペレーター）としては存在しませんでした。そこまで使われる言語ではなかった？？） ECMAScript2016 (ES7) から ** 演算子 で指数計算ができるようになりました。 あわせて指数演算の算術演算を伴う代入演算（ **= ）もできるようになっているのはポイントです。

構文

a ** b

上記の計算であれば「a の b 乗」を計算できます。 a が底で、b が指数です。

サンプルコード

console.log(arr.includes("d"));  // -> false
console.log(2 ** 4);             // -> 16

var a = 2, b = 8;
a **= b;                         // a = a ** b
console.log(a);                  // -> 256

対応状況

2018年10月現在で利用できるのは IE11 以外のブラウザ、Node.js は ver 8 以上で使えるようです。 基本的にはどの環境でも使えると思っていい状況になっています。

今回は「ECMAScript2016 (ES7)」についてまとめました。 参考になったでしょうか？ 本記事がお役に立っていると嬉しいです！！

参考記事

• GitHub - tc39 / Array.prototype.includes
• GitHub - rwaldron/exponentiation-operator
• ECMAScript compatibility table - 2016 plus

今回は「ExcelVBA で使える Glob ユーテリティ」についてまとめます。

VBScriptにありそうでなかった Glob ユーテリティ を作成したので、その解説と使い方についてまとめておきます。 このクラスを利用すると、Glob形式で指定したフォルダ配下のファイルや特定文字列を含んだファイルの絶対パスの一覧を取得が簡単にできます。

Globとは

ファイル検索などで利用される、ワイルドカードなどを使ったファイル名の指定方法です。

拡張子が 「xlsx」であれば「*.xlsx」といった指定で検索できます。 任意の深さのフォルダであれば「**」を使います。例えば「C:¥¥testcase」配下にある任意深さの「xlsx」ファイルであれば「C:¥¥testcase¥**¥*.xlsx」のように指定します。

使い方

ここでは「利用までの準備」と「指定方法の例」の2つについて解説します。

利用までの準備

以下の手順に記載はありませんが、内部的に .NET Framework 3.5 を利用しています。 Windows 10 では標準で入っていないので .NET Framework 3.5 を有効にしてからご利用ください。

1. 以下のリンクからクラスファイルをダウンロード

   GitHub - garafu/vb-glob

   

2. VBAのエディタでインポート

   

3. 任意の場所で利用

   

   Sub Main()
       Dim g, list, item
       Set g = New Glob
       Set list = g.Search("D:\Work\Projects\vbscript\**\[a-z]+\*.vbs")
       For Each item In list
           Debug.Print item
       Next
   End Sub
   

   Glob はクラスなので New して Set してください。 唯一利用できるメソッドが Search(path as string) です。 指定された Globパス に合致する絶対パス一覧を取得します。 戻り値は .NET Framework の ArrayList になっているため、Set で受け取ってください。

指定方法の例

以下には使いそうなGlob形式パス指定の具体例を載せます。

• 「C:\testcase」直下にある「.xlsx」ファイルを探す

  C:\testcase\*.xlsx

• 「C:\testcase」直下にある「.xlsx」ないし「.xls」ファイルを探す

  C:\testcase\*.xls(x)?

• 「C:\testcase」配下にある「.xlsx」ないし「.xls」ファイルを再帰的に探す

  C:\testcase\**\*.xls(x)?

ソースコード

ソースコードは GitHub 上に公開しています。 何かあれば Issues へご連絡ください。

• GitHub - garafu / vb-glob

今回は Excel VBA で Globパス を利用するユーテリティについてまとめました。 参考になったでしょうか？ 本記事がお役に立っていると嬉しいです！！

今回は「VBScriptでAccessを操作する方法」についてまとめます。

アプリケーションの起動/終了

インスタンス生成することで起動し、Quit を実行することで終了できる。

Sub Main()
  Dim objAccess : Set objAccess = CreateObject("Access.Application")
  objAccess.Visible = True
  
  ' 何か処理…
  
  objAccess.Quit
  Set objAccess = Nothing
End Sub

Main

データベースへ接続/切断

接続文字列 strConnection に含まれるファイルパス strFilePath は絶対パスになるよう構成する。

VBScriptなので接続文字列を組み立てているが、Access VBA を利用するのであれば CurrentProject.Connection に接続文字列があるので、これを利用すると簡単。

Sub Main()
  Dim objAccess, strFilePath, strConnection, objConnection, objRecordset, strQuery

  ' Accessオブジェクト生成
  Set objAccess = CreateObject("Access.Application")
  objAccess.Visible = True

  ' DB接続文字列
  strFilePath = GetCurrentDirectory() & "\Database1.accdb"
  strConnection = "Provider=Microsoft.ACE.OLEDB.12.0;" & _
                  "Data Source=" & strFilePath & ";"

  ' 接続
  Set objConnection = CreateObject("ADODB.Connection")
  objConnection.Open strConnection
  
  ' DB操作…
  
  ' 切断
  objConnection.Close

  objAccess.Quit
  Set objConnection = Nothing
  Set objAccess = Nothing
End Sub

Function GetCurrentDirectory()
  Dim objShell : Set objShell = CreateObject("WScript.Shell")
  GetCurrentDirectory = objShell.CurrentDirectory
End Function

Main

参考記事

• MSDN - Connection オブジェクト
• MSDN - Open、Close メソッドの例 (VBScript)
• REONTOSANTA - VBScriptでAccessのデータを操作する

テーブルの操作

テーブル作成

ADODB.Command を利用して SQL によるテーブル作成を行う。 利用できるデータ型については下の表を参照。

Sub Main()
  Dim objAccess, strFilePath, strConnection, objConnection, objCommand
  Set objAccess = CreateObject("Access.Application")
  objAccess.Visible = False

  ' DB接続文字列
  strFilePath = GetCurrentDirectory() & "\Database1.accdb"
  strConnection = "Provider=Microsoft.ACE.OLEDB.12.0;" & _
                  "Data Source=" & strFilePath & ";"

  ' 接続
  Set objConnection = CreateObject("ADODB.Connection")
  objConnection.Open strConnection

  ' クエリ実行
  Set objCommand = CreateObject("ADODB.Command")
  objCommand.ActiveConnection = objConnection
  objCommand.CommandText = "CREATE TABLE [T_COMPANY] (" & _ 
                           "  [ID]            COUNTER," & _ 
                           "  [DISPLAY_NAME]  TEXT(128) NOT NULL," & _ 
                           "  [REGIST_DATE]   DATE," & _ 
                           "  PRIMARY KEY([ID], [DISPLAY_NAME])" & _ 
                           ");"
  objCommand.Execute

  ' 切断
  objConnection.Close

  objAccess.Quit
  Set objCommand = Nothing
  Set objConnection = Nothing
  Set objAccess = Nothing
End Sub

Function GetCurrentDirectory()
  Dim objShell : Set objShell = CreateObject("WScript.Shell")
  GetCurrentDirectory = objShell.CurrentDirectory
End Function

Main

テーブル削除

テーブル作成同様 ADODB.Command を利用してクエリで削除する。

Sub Main()
  Dim objAccess, strFilePath, strConnection, objConnection, objCommand
  Set objAccess = CreateObject("Access.Application")
  objAccess.Visible = False

  ' DB接続文字列
  strFilePath = GetCurrentDirectory() & "\Database1.accdb"
  strConnection = "Provider=Microsoft.ACE.OLEDB.12.0;" & _
                  "Data Source=" & strFilePath & ";"

  ' 接続
  Set objConnection = CreateObject("ADODB.Connection")
  objConnection.Open strConnection

  ' クエリ実行
  Set objCommand = CreateObject("ADODB.Command")
  objCommand.ActiveConnection = objConnection
  objCommand.CommandText = "DROP TABLE [T_COMPANY]"
  objCommand.Execute

  ' 切断
  objConnection.Close

  objAccess.Quit
  Set objCommand = Nothing
  Set objConnection = Nothing
  Set objAccess = Nothing
End Sub

Function GetCurrentDirectory()
  Dim objShell : Set objShell = CreateObject("WScript.Shell")
  GetCurrentDirectory = objShell.CurrentDirectory
End Function

Main

インデックス作成

Sub Main()
  Dim objAccess, strFilePath, strConnection, objConnection, objCommand

  ' Accessオブジェクト生成
  Set objAccess = CreateObject("Access.Application")
  objAccess.Visible = False

  ' DB接続文字列
  strFilePath = GetCurrentDirectory() & "\Database1.accdb"
  strConnection = "Provider=Microsoft.ACE.OLEDB.12.0;" & _
                  "Data Source=" & strFilePath & ";"

  ' 接続
  Set objConnection = CreateObject("ADODB.Connection")
  objConnection.Open strConnection

  ' クエリ実行
  Set objCommand = CreateObject("ADODB.Command")
  objCommand.ActiveConnection = objConnection
  objCommand.CommandText = "CREATE TABLE [T_COMPANY] (" & _ 
                           "  [ID]            COUNTER," & _ 
                           "  [DISPLAY_NAME]  TEXT(128) NOT NULL," & _ 
                           "  [REGIST_DATE]   DATE," & _ 
                           "  PRIMARY KEY([ID])" & _ 
                           ");"
  objCommand.Execute

  objCommand.CommandText = "CREATE INDEX [IX_COMPANY] ON [T_COMPANY] (" & _
                           "  [DISPLAY_NAME] ASC" & _
                           ")"
  objCommand.Execute

  ' 切断
  objConnection.Close

  objAccess.Quit
  Set objCommand = Nothing
  Set objConnection = Nothing
  Set objAccess = Nothing
End Sub

Function GetCurrentDirectory()
  Dim objShell : Set objShell = CreateObject("WScript.Shell")
  GetCurrentDirectory = objShell.CurrentDirectory
End Function

Main

参考記事

• WSH JScriptを使いこなそう ～Access操作～
• Microsoft Docs - Microsoft Access データ型
• MSDN - CREATE INDEX ステートメント

レコードの操作

データ選択（SELECT）

パラメタライズドクエリを実行してデータ取得し、表示するサンプル。

パラメタライズドクエリは PARAMETERS ステートメント を最初に宣言することで利用できる。 変数名は "[]" (角括弧) で囲んで指定する。 変数の具体的な値は PARAMETERS ステートメント で宣言されたパラメータ順に Command.Parameters へ設定する。 （＝ PARAMETERS ステートメント を宣言していれば、実行するクエリの順序は無視してよい。）

取得された Recordset は Do ... Loop で EOF になるまで Recordset.MoveNext で順に取り出して利用する。 Recordset 内のカーソルを移動するメソッドは MoveFirst, MoveLast, MoveNext, MovePrevious がある。

Sub Main()
  Dim objAccess, strFilePath, strConnection, objConnection, objRecordset

  ' Accessオブジェクト生成
  Set objAccess = CreateObject("Access.Application")
  objAccess.Visible = False

  ' DB接続文字列
  strFilePath = GetCurrentDirectory() & "\Database1.accdb"
  strConnection = "Provider=Microsoft.ACE.OLEDB.12.0;" & _
                  "Data Source=" & strFilePath & ";"

  ' 接続
  Set objConnection = CreateObject("ADODB.Connection")
  objConnection.Open strConnection

  ' クエリ作成
  Dim strParameters, strQuery
  strParameters = "PARAMETERS [UserName] TEXT, [Gender] BYTE; "
  strQuery = "SELECT * FROM T_MEMBER" & _
             " WHERE DISPLAY_NAME = [UserName]" & _
             "   AND GENDER = [Gender];"

  ' クエリ実行
  Set objCommand = CreateObject("ADODB.Command")
  objCommand.ActiveConnection = objConnection
  objCommand.CommandText = strParameters & strQuery
  objCommand.CommandType = 1    ' adCmdText = 1
  objCommand.Parameters(0) = "tanaka"
  objCommand.Parameters(1) = 1
  Set objRecordset = objCommand.Execute()

  Do While Not objRecordset.EOF
    wscript.echo objRecordset("ID") & ", " & objRecordset("DISPLAY_NAME")
    objRecordset.MoveNext
  Loop

  ' 切断
  objConnection.Close

  objAccess.Quit
  Set objRecordset = Nothing
  Set objConnection = Nothing
  Set objAccess = Nothing
End Sub

Function GetCurrentDirectory()
  Dim objShell : Set objShell = CreateObject("WScript.Shell")
  GetCurrentDirectory = objShell.CurrentDirectory
End Function

Main

参考記事

• MSDN - PARAMETERS 宣言 (Microsoft Access SQL)
• MSDN - Recordset オブジェクト
• MSDN - Recordset オブジェクトのプロパティ、メソッド、およびイベント

データ追加（INSERT）

INSERT ステートメント で挿入することもできるが、投入量が多い場合バッファ処理される Recordset を利用した以下の INSERT が速い。

Recordset.AddNew を行うとカーソルが新しいレコードとなるため、そのまま投入したいデータを設定する。 一通りデータ投入が終わったタイミングで Recordset.Update を実行することで更新される。

INSERT クエリで実行したい場合、上記「データ選択」で行った ADODB.Command を利用した方法で投入できる。 こちらの方法の場合、毎回 Command.Execute を実行する必要がある。

Sub Main()
  Dim objAccess, strFilePath, strConnection, objConnection, objCommand, objRecordset

  ' Accessオブジェクト生成
  Set objAccess = CreateObject("Access.Application")
  objAccess.Visible = False

  ' DB接続文字列
  strFilePath = GetCurrentDirectory() & "\Database1.accdb"
  strConnection = "Provider=Microsoft.ACE.OLEDB.12.0;" & _
                  "Data Source=" & strFilePath & ";"

  ' 接続
  Set objConnection = CreateObject("ADODB.Connection")
  objConnection.Open strConnection

  ' クエリを使ったデータ投入
  Dim strParameters, strQuery
  strParameters = "PARAMETERS [DisplayName] TEXT, [Gender] BYTE, [LoginDate] DATE;"
  strQuery = "INSERT INTO T_USER (" & _
             " DISPLAY_NAME, GENDER, LOGIN_DATE " & _
             ") VALUES (" & _
             " [DisplayName], [Gender], [LoginDate] " & _
             ");"
  Set objCommand = CreateObject("ADODB.Command")
  objCommand.ActiveConnection = objConnection
  objCommand.CommandText = strParameters & strQuery

  objCommand.Parameters(0) = "mukai with query"
  objCommand.Parameters(1) = 1
  objCommand.Parameters(2) = "2018/9/30"
  objCommand.Execute

  objCommand.Parameters(0) = "furuya with query"
  objCommand.Parameters(1) = 2
  objCommand.Parameters(2) = "2018/3/1"
  objCommand.Execute

  ' Recordsetを使ったデータ投入
  Const adOpenStatic = 3        ' https://msdn.microsoft.com/ja-jp/library/cc389787.aspx
  Const adLockOptimistic = 3    ' https://msdn.microsoft.com/ja-jp/library/cc389829.aspx
  Const adCmdTable = 2          ' https://msdn.microsoft.com/ja-jp/library/cc389765.aspx
  Set objRecordset = CreateObject("ADODB.Recordset")
  objRecordset.Open "T_USER", objConnection, adOpenStatic, adLockOptimistic, adCmdTable

  objRecordset.AddNew
  objRecordset("DISPLAY_NAME") = "mukai with recordset"
  objRecordset("GENDER") = 1
  objRecordset("LOGIN_DATE") = "2018/9/30"

  objRecordset.AddNew
  objRecordset("DISPLAY_NAME") = "furuya with recordset"
  objRecordset("GENDER") = 2
  objRecordset("LOGIN_DATE") = "2018/3/1"

  objRecordset.Update

  ' 切断
  objConnection.Close

  objAccess.Quit
  Set objRecordset = Nothing
  Set objConnection = Nothing
  Set objAccess = Nothing
End Sub

Function GetCurrentDirectory()
  Dim objShell : Set objShell = CreateObject("WScript.Shell")
  GetCurrentDirectory = objShell.CurrentDirectory
End Function

Main

参考記事

• MSDN - Open メソッド (ADO Recordset)
• MSDN - CursorTypeEnum
• MSDN - LockTypeEnum
• MSDN - CommandTypeEnum
• MSDN - AddNew メソッド

データ更新（UPDATE）

クエリを使った更新を行う場合、WHERE 句 で指定するカラム名を テーブル名.カラム名 という指定をした方が良い。 ID はテーブル名もあわせて指定しないと条件指定が有効に働かず全量更新されてしまう。 他のカラムはテーブル名指定しなくても有効に条件指定が効く。

Recordsetを使った更新を行う場合、Find で対象を検索して削除する。 検索して見つからなかった場合、カーソルが末端に行く（ Recordset.EOF ) ので、正しく検索できたかは Recordset.EOF で確認する。 連続操作する場合、検索開始位置を最初の場所（ Recordset.MoveFirst ）へ移動しないと正しく検索できない懸念があるので注意。

Sub Main()
  Dim objAccess, strFilePath, strConnection, objConnection, objCommand, objRecordset

  ' Accessオブジェクト生成
  Set objAccess = CreateObject("Access.Application")
  objAccess.Visible = False

  ' DB接続文字列
  strFilePath = GetCurrentDirectory() & "\Database1.accdb"
  strConnection = "Provider=Microsoft.ACE.OLEDB.12.0;" & _
                  "Data Source=" & strFilePath & ";"

  ' 接続
  Set objConnection = CreateObject("ADODB.Connection")
  objConnection.Open strConnection

  ' クエリを使ったデータ更新
  Dim strParameters, strQuery
  strParameters = "PARAMETERS [Id] LONG, [DisplayName] TEXT;"
  strQuery = "UPDATE T_USER" & _
             "   SET T_USER.DISPLAY_NAME=[DisplayName]" & _
             " WHERE T_USER.ID=[Id];"

  Set objCommand = CreateObject("ADODB.Command")
  objCommand.ActiveConnection = objConnection
  objCommand.CommandText = strParameters & strQuery
  objCommand.Parameters(0) = 1
  objCommand.Parameters(1) = "ほげほげ"
  objCommand.Execute

  ' Recordsetを使ったデータ更新
  Const adOpenStatic = 3        ' https://msdn.microsoft.com/ja-jp/library/cc389787.aspx
  Const adLockOptimistic = 3    ' https://msdn.microsoft.com/ja-jp/library/cc389829.aspx
  Const adCmdTable = 2          ' https://msdn.microsoft.com/ja-jp/library/cc389765.aspx
  Set objRecordset = CreateObject("ADODB.Recordset")
  objRecordset.Open "T_USER", objConnection, adOpenStatic, adLockOptimistic, adCmdTable
  objRecordset.Find "ID=2"
  If Not objRecordset.EOF Then
    objRecordset("DISPLAY_NAME") = "ほげ２"
    objRecordset.Update
  End If

  ' 切断
  objConnection.Close

  objAccess.Quit
  Set objRecordset = Nothing
  Set objConnection = Nothing
  Set objAccess = Nothing
End Sub

Function GetCurrentDirectory()
  Dim objShell : Set objShell = CreateObject("WScript.Shell")
  GetCurrentDirectory = objShell.CurrentDirectory
End Function

Main

参考記事

• MSDN - Update メソッド
• MSDN - Find メソッド

データ削除（DELETE）

基本的に注意すべき箇所は UPDATE と同じ。

Sub Main()
  Dim objAccess, strFilePath, strConnection, objConnection, objCommand, objRecordset

  ' Accessオブジェクト生成
  Set objAccess = CreateObject("Access.Application")
  objAccess.Visible = False

  ' DB接続文字列
  strFilePath = GetCurrentDirectory() & "\Database1.accdb"
  strConnection = "Provider=Microsoft.ACE.OLEDB.12.0;" & _
                  "Data Source=" & strFilePath & ";"

  ' 接続
  Set objConnection = CreateObject("ADODB.Connection")
  objConnection.Open strConnection

  ' クエリを使ったデータ削除
  Dim strParameters, strQuery
  strParameters = "PARAMETERS [Id] LONG;"
  strQuery = "DELETE FROM T_USER" & _
             " WHERE T_USER.ID=[Id];"

  Set objCommand = CreateObject("ADODB.Command")
  objCommand.ActiveConnection = objConnection
  objCommand.CommandText = strParameters & strQuery
  objCommand.Parameters(0) = 3
  objCommand.Execute

  ' Recordsetを使ったデータ削除
  Const adOpenStatic = 3        ' https://msdn.microsoft.com/ja-jp/library/cc389787.aspx
  Const adLockOptimistic = 3    ' https://msdn.microsoft.com/ja-jp/library/cc389829.aspx
  Const adCmdTable = 2          ' https://msdn.microsoft.com/ja-jp/library/cc389765.aspx
  Set objRecordset = CreateObject("ADODB.Recordset")
  objRecordset.Open "T_USER", objConnection, adOpenStatic, adLockOptimistic, adCmdTable
  objRecordset.Find "ID=2"
  If Not objRecordset.EOF Then
    objRecordset.Delete
  End If

  ' 切断
  objConnection.Close

  objAccess.Quit
  Set objRecordset = Nothing
  Set objConnection = Nothing
  Set objAccess = Nothing
End Sub

Function GetCurrentDirectory()
  Dim objShell : Set objShell = CreateObject("WScript.Shell")
  GetCurrentDirectory = objShell.CurrentDirectory
End Function

Main

参考記事

• MSDN - Delete メソッド (ADO Recordset)

今回は「VBScript で Access を操作する方法」についてまとめました。 参考になったでしょうか？ 本記事がお役に立っていると嬉しいです！！

今回は「VBScriptでExcelを操作する方法」についてまとめます。

Excel や Access でも スクリプト が書けますが、Officeアプリ上のVBは「VBA」と呼ぶようです。 今回のまとめは 「VBScript」 なので、アプリケーションの起動など出だし部分は「VBA」と若干異なる箇所があります。

アプリケーションの起動/終了

CreateObject でインスタンス生成すればアプリケーションは起動する。 ただし Visible = True にしないと画面自体は表示されない。 たま、 ScreenUpdating をスクリプト処理中 OFF となるよう指定しておくと画面描画されなくなるのでスクリプト処理が高速化する。

' Mainサブルーチン
Sub Main ()
  On Error Resume Next

  ' Excelアプリケーションのインスタンス生成
  Dim objXls : Set objXls = CreateObject("Excel.Application")
  If Not objXls Then Exit Sub

  ' Excelの表示
  objXls.Visible = True
  objXls.ScreenUpdating = False

  '
  ' いろいろ処理する…
  '

  ' Excelの終了
  objXls.ScreenUpdating = True
  objXls.Quit

  ' インスタンスの破棄
  Set objXls = Nothing
End Sub

' Mainサブルーチンの実行
Main

参考

• MSDN - Application object

ブックの操作

新規ブック作成

Sub Main ()
  On Error Resume Next

  Dim objXls, objWorkbook
  Set objXls = CreateObject("Excel.Application")
  If Not objXls Then Exit Sub
  objXls.Visible = True

  ' Workbookを新規作成
  Set objWorkbook = objXls.Workbooks.Add()

  ' …いろいろ処理する…

  ' Workbookを閉じる
  objWorkbook.Close

  objXls.Quit
  Set objWorkbook = Nothing
  Set objXls = Nothing
End Sub

Main

ブックを開く/閉じる

開きたい Excel ファイルは絶対パスで指定してあげる。

Sub Main ()
  On Error Resume Next

  Dim objXls, objWorkbook
  Set objXls = CreateObject("Excel.Application")
  If Not objXls Then Exit Sub
  objXls.Visible = True

  ' Workbookを開く
  Set objWorkbook = objXls.Workbooks.Open(GetCurrentDirectory() & "\test.xlsx")

  ' …いろいろ処理する…

  ' Workbookを閉じる
  objWorkbook.Close

  objXls.Quit
  Set objWorkbook = Nothing
  Set objXls = Nothing
End Sub

Function GetCurrentDirectory()
  Dim objShell : Set objShell = CreateObject("WScript.Shell")
  GetCurrentDirectory = objShell.CurrentDirectory
End Function

Main

ブックを保存する

上書き保存

Sub Main ()
  On Error Resume Next

  Dim objXls, objWorkbook
  Set objXls = CreateObject("Excel.Application")
  If Not objXls Then Exit Sub
  objXls.Visible = True

  ' Workbookを開く
  Set objWorkbook = objXls.Workbooks.Open(GetCurrentDirectory() & "\test.xlsx")

  ' …いろいろ処理する…

  ' Workbookを保存
  objWorkbook.Save

  objWorkbook.Close
  objXls.Quit
  Set objWorkbook = Nothing
  Set objXls = Nothing
End Sub

Function GetCurrentDirectory()
  On Error Resume Next

  Dim objShell : Set objShell = CreateObject("WScript.Shell")
  GetCurrentDirectory = objShell.CurrentDirectory
End Function

Main

名前を付けて保存

Sub Main ()
  On Error Resume Next

  Dim objXls, objWorkbook
  Set objXls = CreateObject("Excel.Application")
  If Not objXls Then Exit Sub
  objXls.Visible = True

  ' Workbookを開く
  Set objWorkbook = objXls.Workbooks.Open(GetCurrentDirectory() & "\test.xlsx")

  ' …いろいろ処理する…

  ' Workbookを保存
  objWorkbook.SaveAs(GetCurrentDirectory() & "\test2.xlsx")

  objWorkbook.Close
  objXls.Quit
  Set objWorkbook = Nothing
  Set objXls = Nothing
End Sub

Function GetCurrentDirectory()
  On Error Resume Next
  Dim objShell : Set objShell = CreateObject("WScript.Shell")
  GetCurrentDirectory = objShell.CurrentDirectory
End Function

Main

参考

• MSDN - Workbooks object
• MSDN - Workbook object

シートの操作

シート名一覧の取得

Sub Main ()
  On Error Resume Next

  Dim objXls, objWorkbook, objSheet
  Set objXls = CreateObject("Excel.Application")
  If Not objXls Then Exit Sub
  Set objWorkbook = objXls.Workbooks.Open(GetCurrentDirectory() & "\test.xlsx")
  objXls.Visible = False

  ' シート名一覧を取得する
  For i = 1 To objWorkbook.Sheets.Count
    Set objSheet = objWorkbook.Sheets(i)
    If objSheet.Visible Then
      wscript.echo objSheet.Name
    End If
  Next

  objWorkbook.Close
  objXls.Quit
  Set objWorkbook = Nothing
  Set objXls = Nothing
End Sub

Function GetCurrentDirectory()
  On Error Resume Next
  Dim objShell : Set objShell = CreateObject("WScript.Shell")
  GetCurrentDirectory = objShell.CurrentDirectory
End Function

Main

シート名を指定してアクティブにする

Sub Main ()
  On Error Resume Next

  Dim objXls, objWorkbook, objSheet
  Set objXls = CreateObject("Excel.Application")
  If Not objXls Then Exit Sub
  Set objWorkbook = objXls.Workbooks.Open(GetCurrentDirectory() & "\test.xlsx")
  objXls.Visible = True

  ' シート名を名称で指定して取得。1から始まるインデックスで指定もできる。
  Set objSheet = objXls.Sheets("Sheet4")

  ' アクティブシートに設定
  objSheet.Activate

  ' …いろいろ処理する…

  objWorkbook.Close
  objXls.Quit
  Set objWorkbook = Nothing
  Set objXls = Nothing
End Sub

Function GetCurrentDirectory()
  On Error Resume Next
  Dim objShell : Set objShell = CreateObject("WScript.Shell")
  GetCurrentDirectory = objShell.CurrentDirectory
End Function

Main

シートを追加/削除

Sub Main ()
  On Error Resume Next

  Dim objXls, objWorkbook, objSheet1, objSheet2
  Set objXls = CreateObject("Excel.Application")
  If Not objXls Then Exit Sub
  objXls.Visible = True
  Set objWorkbook = objXls.Workbooks.Open(GetCurrentDirectory() & "\test.xlsx")

  ' 先頭に新規シートを追加
  Set objSheet1 = objXls.Sheets.Add(objXls.Sheets(1)) 

  ' 末尾に新規シートを追加
  Set objSheet2 = objXls.Sheets.Add( ,objXls.Sheets(objXls.Sheets.Count)) 

  ' シート名を指定して削除。
  objXls.DisplayAlerts = False      ' データがあるとアラート表示されるので一時的に消す。
  objXls.Sheets("Sheet1").Delete
  objXls.DisplayAlerts = True

  objWorkbook.Close
  objXls.Quit
  Set objWorkbook = Nothing
  Set objXls = Nothing
End Sub

Function GetCurrentDirectory()
  On Error Resume Next
  Dim objShell : Set objShell = CreateObject("WScript.Shell")
  GetCurrentDirectory = objShell.CurrentDirectory
End Function

Main

シート名を変更

Sub Main ()
  On Error Resume Next

  Dim objXls, objWorkbook, objSheet1, objSheet2
  Set objXls = CreateObject("Excel.Application")
  If Not objXls Then Exit Sub
  objXls.Visible = True
  Set objWorkbook = objXls.Workbooks.Open(GetCurrentDirectory() & "\test.xlsx")

  ' "Sheet1" を "シートx" に変更
  objWorkbook.Sheets("Sheet1").Name = "シートx"

  objWorkbook.Close
  objXls.Quit
  Set objWorkbook = Nothing
  Set objXls = Nothing
End Sub

Function GetCurrentDirectory()
  On Error Resume Next
  Dim objShell : Set objShell = CreateObject("WScript.Shell")
  GetCurrentDirectory = objShell.CurrentDirectory
End Function

Main

セルの操作

データのあるセル範囲を取得

データのあるセルは Worksheet.UsedRange で取得きる。 取得された Range にオフセットがある場合、オフセットセル数は Range.Row および Range.Column がオフセットになる。

Sub Main ()
  On Error Resume Next

  Dim objXls, objWorkbook, objSheet, objRange, intR, intC
  Set objXls = CreateObject("Excel.Application")
  If Not objXls Then Exit Sub
  objXls.Visible = False
  objXls.ScreenUpdating = False
  Set objWorkbook = objXls.Workbooks.Open(GetCurrentDirectory() & "\test.xlsx")
  Set objSheet = objWorkbook.Sheets("Sheet1")

  ' データのある範囲を取得
  Set objRange = objSheet.UsedRange

  ' データ範囲を表示
  For intR = 1 To objRange.Rows.Count
    For intC = 1 To objRange.Columns.Count
      wscript.echo _ 
        "[" & objRange.Row + intR - 1 & ","  & objRange.Column + intC - 1 & "]" & _
        objRange(intR, intC).Text
    Next
  Next

  objWorkbook.Close
  objXls.Quit
  Set objWorkbook = Nothing
  Set objXls = Nothing
End Sub

Function GetCurrentDirectory()
  On Error Resume Next
  Dim objShell : Set objShell = CreateObject("WScript.Shell")
  GetCurrentDirectory = objShell.CurrentDirectory
End Function

Main

セルの値を取得

Range.Value でも値は取れるがシリアル値になる。 日付やパーセンテージは表示されている値で取得したほうが良いので Range.Text で値を取得する。

Sub Main ()
  On Error Resume Next

  Dim objXls, objWorkbook, objSheet, objRange
  Set objXls = CreateObject("Excel.Application")
  If Not objXls Then Exit Sub
  objXls.Visible = False
  objXls.ScreenUpdating = False
  Set objWorkbook = objXls.Workbooks.Open(GetCurrentDirectory() & "\test.xlsx")
  Set objSheet = objWorkbook.Sheets("Sheet1")

  ' データ取得範囲を指定
  Set objRange = objSheet.Range("A1:E2")

  ' データを表示
  For intR = 1 To objRange.Rows.Count
    For intC = 1 To objRange.Columns.Count
      wscript.echo _ 
        "[" & objRange.Row + intR - 1 & ","  & objRange.Column + intC - 1 & "]" & _
        objRange(intR, intC).Text
    Next
  Next

  objWorkbook.Close
  objXls.Quit
  Set objWorkbook = Nothing
  Set objXls = Nothing
End Sub

Function GetCurrentDirectory()
  On Error Resume Next
  Dim objShell : Set objShell = CreateObject("WScript.Shell")
  GetCurrentDirectory = objShell.CurrentDirectory
End Function

Main

セルに値を書き込む

Sub Main ()
  On Error Resume Next

  Dim objXls, objWorkbook, objSheet, objRange
  Set objXls = CreateObject("Excel.Application")
  If Not objXls Then Exit Sub
  objXls.Visible = True
  objXls.ScreenUpdating = True
  Set objWorkbook = objXls.Workbooks.Open(GetCurrentDirectory() & "\test.xlsx")
  Set objSheet = objWorkbook.Sheets("Sheet1")

  ' 標準
  objSheet.Cells(1,1).Value = "あ"
  objSheet.Cells(1,1).NumberFormatLocal = "G/標準"

  ' 文字列
  objSheet.Cells(1,2).Value = "い"
  objSheet.Cells(1,2).NumberFormatLocal = "@"

  ' 数値
  objSheet.Cells(1,3).Value = "100.123"
  objSheet.Cells(1,3).NumberFormatLocal = "0_);[赤](0)"

  ' 日付
  objSheet.Cells(1,4).Value = "2018/9/1"
  objSheet.Cells(1,4).NumberFormatLocal = "yyyy/mm/dd"

  ' 時刻
  objSheet.Cells(1,5).Value = "20:00"
  objSheet.Cells(1,5).NumberFormatLocal = "hh:mm"

  ' パーセンテージ
  objSheet.Cells(1,6).Value = "60%"
  objSheet.Cells(1,6).NumberFormatLocal = "0%"

  objWorkbook.Close
  objXls.Quit
  Set objWorkbook = Nothing
  Set objXls = Nothing
End Sub

Function GetCurrentDirectory()
  On Error Resume Next
  Dim objShell : Set objShell = CreateObject("WScript.Shell")
  GetCurrentDirectory = objShell.CurrentDirectory
End Function

Main

参考

• Excel VBA @Workshop - セルの表示形式を設定する
• MSDN - Range.NumberFormatLocal

セルの書式を設定

罫線の線種や太さを示す定数が VBScript 上では使えないので直接値を指定する。 Excel VBA などでは定数が使えるので定数を使うと簡単。

Sub Main ()
  On Error Resume Next

  Dim objXls, objWorkbook, objSheet, objCell
  Set objXls = CreateObject("Excel.Application")
  If Not objXls Then Exit Sub
  objXls.Visible = True
  objXls.ScreenUpdating = False
  Set objWorkbook = objXls.Workbooks.Open(GetCurrentDirectory() & "\test.xlsx")
  Set objSheet = objWorkbook.Sheets("Sheet1")
  Set objCell = objSheet.Range("B3")
  objCell.Value = "ほげほげほげお"

  ' 文字
  objCell.Font.Name = "メイリオ"                      ' フォント
  objCell.Font.Color = RGB(256, 0, 0)     ' 文字色
  objCell.Font.Size = 12                  ' サイズ
  objCell.Font.Italic = True                            ' イタリック
  objCell.Font.Bold = True                                ' 太字

  ' 背景
  objCell.Interior.Color = RGB(192, 192, 192)

  ' 罫線
  objCell.Borders.LineStyle = 1           ' 線種
  objCell.Borders.Weight = 1              ' 太さ
  objCell.Borders.Color = RGB(0, 0, 128)  ' 色

  objWorkbook.Close
  objXls.Quit
  Set objWorkbook = Nothing
  Set objXls = Nothing
End Sub

Function GetCurrentDirectory()
  On Error Resume Next
  Dim objShell : Set objShell = CreateObject("WScript.Shell")
  GetCurrentDirectory = objShell.CurrentDirectory
End Function

Main

参考

• Tipsfound - VBA セルの罫線を設定する
• MSDN - Font object
• MSDN - Interior object
• MSDN - Borders object
• MSDN = XlLineStyle
• MSDN - XlBorderWeight

今回は「VBScript で Excel を操作する方法」についてまとめました。 参考になったでしょうか？ 本記事がお役に立っていると嬉しいです！！

今回は「VBScriptの関数利用時に使う丸括弧」についてまとめます。

VBScript で .NET Framework のクラスを利用としていると、「Sub プロシージャ を呼び出すときにかっこを使うことはできません」というエラーが出たので原因を調べていました。 VBScript でまだ知らないルールがあったので、覚書にこの記事に残しておきます。

丸括弧の意味は4つ

VBScriptの構文において、丸括弧には以下に示す4パターンの意味がある。

1. 算術演算で先に計算することを示す丸括弧 （例：avg = (arg1 + arg2) / 2）
2. 配列の要素番号を示す丸括弧 （例：item = list(3)）
3. 引数リストの範囲を示す丸括弧 （例：retval = proc(arg1, arg2)）
4. 参照渡しを値渡しに変更する丸括弧 （例：retval = proc(arg1, (arg2))）

上記のうち 1 と 2 は理解しやすい内容だが、2 と 3 は分かりにくいので以下に補足する。 例えば、次のような関数呼び出しを行っている文があったとき、

retval = procedure(arg1, (arg2))

外側の丸括弧 (arg1, (arg2)) が「引数リストの範囲を示す丸括弧」、 内側の丸括弧 (arg2) が「参照渡しを値渡しに変更する丸括弧」を示している。

ちなみに…VBScriptにおいて関数の引数はデフォルト参照渡しになる点には注意。

丸括弧の適用ルール

前述の丸括弧の意味のうち3番目の「引数リストの範囲を示す丸括弧」には、さらに別のルールがある。 具体的には以下に示すようなルールがある。

• Callステートメント を利用して関数呼び出しをする場合、引数リストを示す丸括弧を記述する。
  （例：Call proc1(arg1)）
• 戻り値への代入を伴う関数呼び出しをする場合、引数リストを示す丸括弧を記述する。
  （例：Set retval = proc2(arg1, arg2)）
• 上記以外の場合、引数リストは丸括弧で囲まない。
  （例：proc2 arg1, arg2）

これらのルールは「参照渡しを値渡しに変更する丸括弧」ルールとは別になる。

まとめ

上記ルールのうち関数呼び出しに関してまとめると以下のような例になります。

• 関数 func に対して a も b も参照渡し

  func a, b
  Call func(a, b)
  retval = func(a, b)
  

• 関数 func に対して a を参照渡し、 b を値渡し

  func a, (b)
  Call func(a, (b))
  retval = func(a, (b))
  

今回は「VBScriptにおける丸括弧」、特に「関数利用時における丸括弧の利用ルール」についてまとめました。 参考になったでしょうか？ 本記事がお役に立っていると嬉しいです！！

参考記事

• Microsoft Developer - What do you mean "cannot use parentheses?"
• 実験記録　No.02 - 【解説】VBSの「Sub プロシージャを呼び出すときに、かっこを使うことはできません」エラーの詳しい解説
• Office TANAKA - 括弧はどんなときに使うの？

今回は「VBScriptの基本」についてまとめます。 VBScript は OLEオブジェクト を読み込むことで拡張できますが、ここでは基本的な機能に絞ってまとめました。

ちょっと多いですが…一通り読めば基礎力がつくはず！

概要

スクリプト言語。スクリプトなのでコンパイル不要ですぐ実行できる。 特徴は以下の3点。

• 動的型付け
• OLEクライアント
• オブジェクト指向

決まったエントリーポイントはないので、スクリプトを実行すると上から順に実行される。

字句構造

文字

変数や関数で利用可能な文字や命名制限は以下の通り。

• 利用可能な文字はアルファベット、数字、アンダースコア。
  （ドル記号、ピリオドなどアンダースコア以外の記号は利用不可）
• 先頭文字は、アルファベットであること。
• 半角 256 文字以内 であること。（←MSのサイトには255以内と書いてあるが、実際は256以内までOKだった。）
• 大文字小文字は区別しない。
• 変数宣言を行った適用範囲内で同じ変数名を複数使用しないこと。
  （関数はエラーにならないが後勝ちになる。紛らわしいので避けるのが望ましい。）

" _"(半角スペース + アンダースコア)

VBScriptでは式の終わりを改行で表す。

Wscript.echo "Hello"
Wscript.echo "World"

式を複数行に渡って記述したい場合、行末に 「" "(半角スペース) + "_"(アンダースコア)」 を記述する。

Wscript.echo "Hello " + _
             "World"

コメント

コメントは Rem または "'"(シングルクォート) で記述する。 行コメントのみでブロックコメントは存在しない。

Rem コメント

' コメント

式の末尾にコメントしたい場合、:Rem を使うか "'"(シングルクォート) を使う。

Dim str1, str2
str1 = "Hello" :Rem 1つ目のコメント
str2 = "World" ' 2つ目のコメント

予約語

以下にあげる単語は予約語なので変数名や関数名に指定できない。 大文字小文字区別しない点も注意。

データ型

バリアント型（Variant）と呼ばれるデータ型のみを利用。 バリアント型は利用されたときの状況に応じて内部処理用のサブタイプを変更する特殊なデータ型。

内部処理で利用されるサブタイプは以下の通り。

変数 と 定数

スカラ変数

Dim ステートメント を利用して宣言する。 複数同時に宣言する場合は ","(カンマ) で区切って宣言する。 変数名はハンガリアン記法（接頭辞に型名をつける記法）が一般的。

Dim intA
Dim blnB, bytC, strD

配列変数

配列を宣言する場合は "()"(丸括弧) で表現する。 数値指定した場合は固定長の配列が準備され、数値指定しない場合は動的配列が準備される。 多次元配列は ","(カンマ) で区切って宣言する。 60次元まで宣言可能。

Dim aintScores(10)       ' 配列の場合 「a + 型を示す接頭辞 + 変数名」 で宣言する
Dim aintArea(4, 4)

宣言と同時に初期化

宣言と同時に初期化したい場合、 ":"(コロン) でつなげて記述する。 ":"(コロン) を使うと 1行 に複数式が記述できるようになる。

Dim strMessage : strMessage = "Hello World"
Dim astrMsg(2) : astrMsg(0) = "hoge" : astrMsg(1) = "foo"
Dim objShell : objShell = WScript.CreateObject("WScript.Shell")

変数宣言の強制

既存変数名の入力ミスや変数のスコープが分かりづらいコードにおける競合を避けるため、変数宣言の強制を行うことが望ましい。 変数宣言の強制を行うにはコードの最初に Option Explicit を宣言する。

Option Explicit
strMessage = "hoge"   ' エラーになる

定数

Const ステートメント を利用して定数宣言する。 ユーザー定義の定数名は接頭辞に "vb" または "con" をつける（ "vb" は組み込み定数で利用されているので "con" を使うのがよさそう）。

Const conMaxAge = 49

式と演算子

代入、割当

"="(イコール) 演算子

スカラ値の単純代入には "="(イコール) を利用する。

Dim intScore
intScore = 100

ReDim ステートメント

動的配列の宣言、メモリ領域の再割り当てには ReDim ステートメント を利用する。 Preserve キーワード を利用すると格納済みの既存データを維持したまま再割り当てすることができる。 多次元配列の場合、最後の次元だけが変更可能となっておりそれ以外の次元は変更できない点に注意。

Dim aintA()
ReDim aintA(1, 2, 3)
...
ReDim Preserve aintA(1, 2, 5)

Set ステートメント

オブジェクトへの参照を変数またはプロパティへ代入する場合、 Set ステートメント を利用する。

Dim objFso
Set objFso = WScript.CreateObject("Scripting.FileSystemObject")

算術演算子

2 + 3

2 -3

2 * 3

2 / 3

19 Mod 6.7

論理演算子

blnCond1 And blnCond2

blnCond1 Or blnCond

Not blnCond1

blnCond1 Xor blnCond2

比較演算子

strMsg1 = strMsg2

strMsg1 <> strMsg2

intCost > intPayment

intCost >= intPayment

intCost < intPayment

intCost <= intPayment

objFso1 Is objFso2

文字列演算子

strMsg1 & strMsg2

文

If ... Then ... Else 文

構文1 (単一条件・単一処理)

If <条件> Then <処理>

1行で記述する場合。 条件が真（ True ）となる場合に単一処理を実行する構文。

構文2 (複数条件・複数処理)

If <条件式1> Then
  <処理1>
ElseIf <条件式2> Then
  <処理2>
ElseIf 条件式3> Then
  <処理3>
Else
  <処理4>
End If

複数条件を処理する場合や複数処理を実行する場合。 条件を重ねる場合、ElseIf を連ねることで複数の条件と処理を記述できる。 どこにも当てはまらないケースは Else で記述する。

Select Case 文

構文

Select Case <式>
  Case <値1>, <値2>  ' 複数ケースはカンマ区切り
    <処理1>          ' 次の処理へ流れない
  Case <値3>
    <処理2>
  Case Else
    <処理3>          ' Case Else はデフォルトケース
End Select

いわゆる switch文。breakを記載しないが、各ケースで処理は完結する。 勝手に次のケースへ流れて処理されることはない。 関連して複数条件を指定する場合、値を ","(カンマ) 区切りで指定する。

For ... Next 文

構文

For <カウンタ> = <初期値> To <条件値> [Step <増分値>]
  <処理>
  If <条件式> Then Exit For   ' Exit For でループを途中で抜ける
Next

カウンタが条件値を超えるまでループを繰り返し実行する（for ( カウンタ = 初期値; カウンタ <= 条件値; カウンタ += 増分値) {}）。 条件値に負の値を指定した場合はその値より小さくなるまで繰り返し実行する。 Step を指定しない場合はデフォルトで 1 が指定される（1ずつ増加）。 ループを途中で抜ける場合、Exit For ステートメント を利用する。

For Each ... Next 文

構文

For Each <変数> In <コレクション>
  <処理>
  If <条件式> Then Exit For
Next

コレクションに含まれる要素数分ループする。

Do ... Loop 文

構文1 (Whileキーワード)

Do While <条件式1>
  <処理>
  If <条件式2> Then Exit Do    ' ループを抜ける
Loop

Do
  <処理>
  If <条件式2> Then Exit Do    ' ループを抜ける
Loop While <条件式1>

条件式が真（ True ）である間、処理が実行される。 途中で処理を抜ける場合、 Exit Do ステートメント を利用する。

構文2 (Untilキーワード)

Do Until <条件式1>
  <処理>
  If <条件式2> Then Exit Do    ' ループを抜ける
Loop

Do
  <処理>
  If <条件式2> Then Exit Do    ' ループを抜ける
Loop Until <条件式1>

条件式が真（ True ）になるまで、処理が実行される。 途中で処理を抜ける場合、 Exit Do ステートメント を利用する。

配列と連想配列

VBScript のデフォルトで利用できる配列と連想配列は以下の2種類。

• Array
• Scripting.Dictionary

Array

VBScriptネイティブサポートされている配列。 ほとんど何もできない…。。

プロパティ

メソッド

（なし）

サンプルコード

' 動的配列の宣言
ReDim astrList(3)

' 指定した要素へ書き込み
astrList(0) = "hoge"

' 指定した要素の読み込み
WScript.echo astrList(0)

' 現在の長さを取得
WScript.echo UBound(astrList)

' 要素の巡回
For i = LBound(astrList) To UBound(astrList)
  WScript.echo astrList(i)
Next

' 配列の長さ変更
ReDim Preserve arr(5)
WScript.echo UBound(arr)

Scripting.Dictionary

WSHの「Scriptランタイム」でサポートされる VBScript ネイティブ 連想配列。

プロパティ

メソッド

サンプルコード

' 宣言
Dim dic : Set dic = CreateObject("Scripting.Dictionary")

' 要素の追加
dic.Add "key1", "val1"
dic.Add "key2", "val2"
dic.Add "key3", "val3"

' 要素の削除
dic.Remove "key2"

' 要素の読み書き
dic.Item("key1") = "hoge"
wscript.echo dic.Item("key1")

' 要素の巡回 1 (for)
Dim keys : keys = dic.Keys()
For i = LBound(keys) To UBound(keys)
  wscript.echo keys(i)
Next

' 要素の巡回 2 (for each)
For Each key In dic
  wscript.echo dic.Item(key)
Next

' 要素の全削除
dic.RemoveAll

プロシージャ（関数）

VBScriptには戻り値によって以下に示す2種類の関数（=プロシージャ）がある。

Sub プロシージャ

戻り値なし。

Function プロシージャ

戻り値あり。

引数の渡し方は以下に示す2種類がある。特に指定しなければ参照渡し。

ByRef キーワード

参照渡し。

ByVal キーワード

値渡し。

Sub プロシージャ

Sub <関数名> ( <引数1>, <引数2>, ... )
  <処理>
End Sub

戻り値がない関数を定義する。

Function プロシージャ

Function <関数名> ( <引数1>, <引数2>, ... )
  <処理>
  <関数名> = <戻り値>
End Function

戻り値がある関数を定義する。 戻り値は定義した関数名に対して設定することで返却できる。

クラス

クラスの定義

クラスの宣言には Class ステートメント を利用する。

Class <クラス名>
  <メンバ変数>
  <プロパティ>
  <メンバ関数>
End Class

オブジェクトの生成と破棄

クラスのインスタンス生成には New ステートメント を利用する。 破棄は Nothing を指定する。

' クラス定義
Class Animal
  Public Age
End Class

' 変数宣言
Dim objAnimal

' オブジェクト生成
Set objAnimal = New Animal

' オブジェクト破棄
Set objAnimal = Nothing

アクセス修飾子

利用可能なアクセス修飾子は以下の2つ。

• Public
• Private

コンストラクタ/デストラクタ

コンストラクタは Class_Initialize という名前のメソッド、 デストラクタは Class_Terminate という名前のメソッド。 メソッド名は固定。

Class <クラス名>
  Private Sub Class_Initialize
    <初期化処理>
  End Sub
  
  Private Sub Class_Terminate
    <終端処理>
  End Sub
End Class

メンバ変数

アクセス修飾子に加えて変数名を定義することでメンバ変数が定義できる。 ハンガリアン記法では、メンバ変数の接頭辞（プレフィックス）は一般的に m_ が使われる（グローバル変数 g_ や スタティック変数 s_ があるため）。 ちなみに、VBScript のクラスには スタティック変数やスタティック関数は作れない。

アクセス修飾子を特に指定しない場合、 Public で定義される。

Class <クラス名>
  [Public | Private] <変数名>
End Class

プロパティ

いわゆる Getter / Setter が定義できる。 Getter は Property Get ステートメント を利用して定義する。 Setter は Property Let ステートメント または Property Set ステートメント を利用して定義する。 値渡しが Property Let ステートメント で、参照渡しが Property Set ステートメント 。

アクセス修飾子を特に指定しない場合、 Public で定義される。

Class <クラス名>
  ' Getter
  [Public | Private] Property Get <変数名>
    <処理>
    <変数名> = <戻り値>
  End Property

  ' Setter (値渡し)
  [Public | Private] Property Let <変数名> (<引数>)
    <処理>
  End Property

  ' Setter (参照渡し)
  [Public | Private] Property Set <変数名> (<引数>)
    <処理>
  End Property
End Class

メンバ関数

アクセス修飾子に加えてプロシージャを定義する。 戻り値がない場合 Sub プロシージャ 、戻り値がある場合 Function プロシージャ を利用する。

アクセス修飾子を特に指定しない場合、 Public で定義される。

Class <クラス名>
  [Public | Private] Sub <関数名> ( <引数1>, <引数2>, ... )
    <処理>
  End Sub

  [Public | Private] Function <関数名> ( <引数1>, <引数2>, ... )
    <処理>
    <関数名> = <戻り値>
  End Sub
End Class

継承

VBScript の基本機能として継承は存在していないとのこと。 独自実装が必要そう。

OLEオブジェクト

VBScript では簡単にレジストリ登録済みDLLの呼び出しができる。 呼び出すときは CreateObject(<クラス名>) を利用する。 指定するクラス名はレジストリ上の 「HKEY_LOCAL_MACHINE\Software\Classes」 に定義された名前を指定する。

Dim obj : Set obj = CreateObject("Scripting.FileSystemObject")

今回は「VBScript の 基本」についてまとめました。 参考になったでしょうか？ 本記事がお役に立っていると嬉しいです！！

参考記事

• MSDN - VBScript概要
• Qiita - プログラムの基本構文が分かる人へのVBScriptのまとめ
• VBScript入門講座
• VBSの家 - Lesson.14 大文字と小文字
• インストラクターのネタ帳 - 変数のプレフィックス一覧
• Black Everyday Company - 【VB系】変数の宣言と初期化を1行で書く（VB.NET,VBA,VBScript）

今回は「テスト観点」についてまとめます。 私の経歴が Webシステム開発 ばかりなので、内容がWebシステム開発を前提に記載している点はご了承ください。。

テスト観点とは

「テスト観点とはテストの切り口」

テスト実施する際、どのような人が設計・実施したとしても漏れ・ダブりが発生しないよう、あらかじめテストの方向性を定義したものです。 テスト観点を一覧化した「テスト観点一覧」を利用することで効率的にテスト設計・実施を行えるようにします。 また、この「テスト観点一覧」は再利用可能な形にしておき、システム改修や他プロジェクトへの適用を行いながら改善していくことでノウハウを蓄積させます。

知見者に頼ってなんとなくテストしてうまくいった！…ではなく、意図的に「うまくいった！」を引き起こすために準備するものです。

テスト観点一覧（サンプル）

とはいえ、ゼロから「テスト観点一覧」を作るのは難しいので多くは何かしらのフレームワークで切り出していくものです。 今回は ISO/IEC 9126 にある 「ソフトウェア品質特性」をベースにサンプルを作ってみました。 基本的には「Webサイト開発」を前提とした「テスト観点一覧」になります。

前述した通り「テスト観点一覧」は育てるものなので、この記事もそのうち更新しているかもしれません…。 そんなときは履歴をつけておくので参考にしてください。

全体

├機能性
│  ├機能テスト
│  │  ├正常系
│  │  ├異常系
│  │  └組み合わせ
│  ├確認テスト
│  │  ├回帰テスト
│  │  └デグレードテスト
│  ├シナリオテスト
│  ├構成テスト
│  ├インストール/アンインストールテスト
│  └セキュリティテスト
│
├信頼性
│  ├ロバストネス
│  ├回復性
│  ├信頼性
│  └負荷
│      ├大容量
│      └多量
│
├使用性
│  ├ユーザビリティ
│  └マニュアル
│
├効率性
│  性能テスト
│  ├ロードテスト
│  ├ストレステスト
│  └ロングランテスト
│
├保守性
│  ├保守性
│  └保全性
│
└移植性
    ├データ互換性
    └環境構成

詳細（機能テスト）

上記で示した全体のうち「機能テスト」だけ以下にもう少し詳細化したものを記載します。

├正常系
│  ├基本機能
│  ├画面遷移
│  ├状態遷移
│  ├設定（保持、変更、反映）
│  ├表示
│  └ユーザーインターフェース（GUI）
├異常系
│  ├異常値入力
│  ├エラー検知/復旧
│  ├異常データ
│  ├記憶装置異常
│  ├異常状態
│  ├異常環境（通信）
│  └異常操作
└組み合わせ
  ├同時動作
  ├割り込み動作
  ├排他処理
  ├互換性
  ├構成
  ├相互運用性
  └オプション/付属品

変更履歴

2018/09/06

初版。

今回は「テスト観点」についてまとめました。 参考になったでしょうか？ 本記事がお役に立っていると嬉しいです！！